I’ll be presenting the RAD Studio 2010 Sneak Peeks in Sydney and Melbourne next week. There are more details here, but if you are in town I’d encourage you to come along. There’s some very cool stuff in this release.

And before you ask, yes, we’re working on other cities. Stay tuned.

Delphi has long had various functions to let you work with the file system, but one of the new features of Delphi 2010 are some nice wrappers for working with files, paths and directories.

IOUtils.pas is the file in question, and it’s definitely worth a look. Each time I’ve had a look in there during the Field Test I’ve found more interesting stuff to play with. While I’m still exploring it, I thought I’d post a few examples to show you the kind of things you can get up to.

Firstly, something easy:

procedure TForm2.Button2Click(Sender: TObject);  
var   
  Path : string; 
begin 
  if not TDirectory.Exists(edtPath.Text) then 
    Caption := 'Invalid Path' 
  else 
    Caption := edtPath.Text;
 
  ListBox1.Clear;

  for Path in TDirectory.GetFiles(edtPath.Text, edtFilter.Text) do 
    Listbox1.Items.Add(Format('Name = %s', [Path])); 
end;

First we check if the path provided in the edtPath edit box exists. Assuming it does, we then use a for..in statement to get back each file in that directory that matches the filter passed in as the second parameter.

If you look a little further in IOUtils.pas, you’ll see TDirectory has a type declared in it called a TFilterPredicate:

TFilterPredicate = reference to function(const Path: string; const SearchRec: TSearchRec): Boolean;

One of the places it is used is in an overloaded version of GetFiles, like so:

procedure TForm2.Button1Click(Sender: TObject); 
var 
  Path : string; 
  FilterPredicate : TDirectory.TFilterPredicate; 
begin 
  if not TDirectory.Exists(edtPath.Text) then 
    Caption := 'Invalid Path' 
  else 
    Caption := edtPath.Text;

  ListBox1.Clear;

  FilterPredicate := function(const Path: string; const SearchRec: TSearchRec): Boolean 
                     begin 
                       Result := (TPath.MatchesPattern(SearchRec.Name, edtFilter.Text, False)) AND 
                                 (SearchRec.Attr = faArchive); 
                     end;

  for Path in TDirectory.GetFiles(edtPath.Text, FilterPredicate) do 
    Listbox1.Items.Add(Format('Name = %s', [Path])); 
end;

We implement the TFilterPredicate anonymous method to check that each file matches a wildcard pattern and that it also has its Archive flag set. We can then pass it into our call to TDirectory.GetFiles and our code in the for..in statement will only be called for files that match our criteria.

This is all fine for a single directory, but what if we want to walk over the full tree of directories? Easy, just alter our code to look like this:

procedure TForm2.Button3Click(Sender: TObject);
var
  Path, Directory : string;
  FilterPredicate : TDirectory.TFilterPredicate;
begin
  if not TDirectory.Exists(edtPath.Text) then
    Caption := 'Invalid Path'
  else
    Caption := edtPath.Text;

  ListBox1.Clear;

  FilterPredicate := function(const Path: string; const SearchRec: TSearchRec): Boolean
                     begin
                       Result := (TPath.MatchesPattern(SearchRec.Name, edtFilter.Text, False)) AND 
                                 (SearchRec.Attr = faArchive);
                     end;

  for Directory in TDirectory.GetDirectories(edtPath.Text, TSearchOption.soAllDirectories, nil) do
    for Path in TDirectory.GetFiles(Directory, FilterPredicate) do
      Listbox1.Items.Add(Format('Name = %s', [Path]));
end;

We add another for..in statement before the existing one. This one for each Directory in TDirectory.GetDirectories. The second parameter indicates whether we only want to get the top level directories in the path we specify, or whether we want to do all directories , all the way down. In this case I’m specifying the latter. The Third parameter is actually another TDirectory.TFilterPredicate, so we could do further filtering of the directories that match, however I’m passing in nil so all directories will match. Just keep your wits about you while testing, and don’t test it with c:\ as I did

One thing to note, TDirectory.GetDirectories returns child directories of the path we’ve specified (and their child directories, etc if you’ve specified TSearchOption.soAllDirectories), but obviously not the path we pass in itself. That probably sounds obvious, but in this example we’ve subtly altered the behaviour a little, because the files in the directory we specify are not checked anymore. Now you’re aware of this, I’m sure you can figure out how to deal.

There’s a whole bunch more that can be done, such as encrypt files, move directories, etc. IOUtils looks to be a really powerful unit, and is well worth a little playing to get familiar with it.